Page MenuHomeHEPForge
Files F9501765

No OneTemporary
Actions

View Options

diff --git a/current_generator/extremal_W_central_qqbar.frm b/current_generator/extremal_W_central_qqbar.frm
new file mode 100644
index 0000000..d46a47f
--- /dev/null
+++ b/current_generator/extremal_W_central_qqbar.frm
@@ -0,0 +1,78 @@
+*/**
+* \brief Calculation of W + jets with central qqbar emission, W emitted from extremal leg
+*
+* TODO: document in developer manual!
+*
+* \authors The HEJ collaboration (see AUTHORS for details)
+* \date 2020
+* \copyright GPLv2 or later
+*/
+#include- include/helspin.frm
+#include- include/write.frm
+
+cf X1a,X4b,V3g,jW;
+i alpha,mu,nu,sigma;
+s h,sqqbar,saq,saqbar,s1q,s1qbar,sbq,sbqbar,s4q,s4qbar;
+cf m2;
+v p,pa,p1,pb,p4,pq,pqbar,pl,plbar,q1,q3,q11,q12,pW;
+
+#do h1={+,-}
+ #do h2={+,-}
+ l [M_cross `h1'`h2'] = -Current(`h1'1, p1, mu, pa)*Current(
+ `h2'1, pq, nu, q1 - pqbar, mu, pqbar
+ );
+ l [M_uncross `h1'`h2'] = Current(`h1'1, p1, mu, pa)*Current(
+ `h2'1, pq, mu, q1 - pq, nu, pqbar
+ );
+ l [M_sym `h1'`h2'] = -i_*Current(`h1'1, p1, mu, pa)*(
+ X1a(mu, nu, sigma) - X4b(mu, nu, sigma) + V3g(mu, nu, sigma)
+ )/sqqbar*Current(`h2'1, pq, sigma, pqbar);
+ #enddo
+#enddo
+multiply jW(-1, pb, p4, plbar, pl);
+* eq:Weffcur1 in developer manual
+id jW(-1, pa?, p1?, plbar?, pl?) = Current(-1, pl, alpha, plbar)*(
+ + Current(-1,p1,alpha,p1+pW,nu,pa)
+ + Current(-1,p1,nu,pa-pW,alpha,pa)
+);
+
+id Current(h?, pq?, mu?, p?, nu?, pqbar?) = Current(h, pq, mu, p, nu, pqbar)/m2(p);
+
+id X1a(mu?, nu?, sigma?) = d_(mu,nu)*m2(q1)*(
+ pa(sigma)/(saq + saqbar) + p1(sigma)/(s1q + s1qbar)
+);
+id X4b(mu?, nu?, sigma?) = d_(mu,nu)*m2(q3)*(
+ pb(sigma)/(sbq + sbqbar) + p4(sigma)/(s4q + s4qbar)
+);
+id V3g(mu?, nu?, sigma?) = (
+ (q1(nu) + pq(nu) + pqbar(nu))*d_(mu, sigma)
+ + (q3(mu) - pq(mu) - pqbar(mu))*d_(nu, sigma)
+ - (q1(sigma) + q3(sigma))*d_(mu, nu)
+);
+
+multiply replace_(pW, pl+plbar);
+multiply replace_(q3, q1-pq-pqbar);
+* replace q1 by sum of lightlike momenta
+multiply replace_(q1, q11-q12);
+.sort
+#call ContractCurrents()
+multiply replace_(
+ sqqbar, m2(pq+pqbar),
+ saq, m2(pa+pq),
+ saqbar, m2(pa+pqbar),
+ s1q, m2(p1+pq),
+ s1qbar, m2(p1+pqbar),
+ sbq, m2(pb+pq),
+ sbqbar, m2(pb+pqbar),
+ s4q, m2(p4+pq),
+ s4qbar, m2(p4+pqbar)
+);
+.sort
+format O4;
+format c;
+#call WriteHeader(`OUTPUT')
+#call WriteOptimised(`OUTPUT',M_uncross,2,pa,p1,pb,p4,pq,pqbar,pl,plbar,q11,q12)
+#call WriteOptimised(`OUTPUT',M_cross,2,pa,p1,pb,p4,pq,pqbar,pl,plbar,q11,q12)
+#call WriteOptimised(`OUTPUT',M_sym,2,pa,p1,pb,p4,pq,pqbar,pl,plbar,q11,q12)
+#call WriteFooter(`OUTPUT')
+.end

File Metadata

Mime Type
text/x-diff
Expires
Sun, Feb 23, 3:02 PM (21 m, 52 s)
Storage Engine
blob
Storage Format
Raw Data
Storage Handle
4486812
Default Alt Text
(2 KB)

Event Timeline