Page Menu
Home
HEPForge
Search
Configure Global Search
Log In
Files
F19251070
acinclude.m4
No One
Temporary
Actions
Download File
Edit File
Delete File
View Transforms
Subscribe
Award Token
Flag For Later
Size
6 KB
Referenced Files
None
Subscribers
None
acinclude.m4
View Options
AC_DEFUN([AC_CHECK_CLHEP],
[
AC_MSG_CHECKING([for CLHEPPATH])
if test -z "$CLHEPPATH"; then
AC_MSG_RESULT([none])
AC_MSG_ERROR([CLHEPPATH not set])
fi
AC_MSG_RESULT([$CLHEPPATH])
AC_MSG_CHECKING([for CLHEPLIB])
if test -z "$CLHEPLIB"; then
for filename in $CLHEPPATH/lib/libCLHEP-?.?.?.?.{so,dylib} $CLHEPPATH/lib/libCLHEP.{so,dylib}; do
if test -e $filename; then
CLHEPLIB=`basename $filename | sed -e 's/^lib/-l/' -e 's/\.\(so\|dylib\)$//'`
fi
done
if test -z "$CLHEPLIB"; then
AC_MSG_RESULT([none])
AC_MSG_ERROR([Cannot find libCLHEP at $CLHEPPATH/lib.])
fi
fi
CLHEPLDFLAGS="-L$CLHEPPATH/lib -R$CLHEPPATH/lib"
AC_MSG_RESULT([$CLHEPLIB])
AC_MSG_CHECKING([for CLHEPINCLUDE])
if test -z "$CLHEPINCLUDE"; then
CLHEPINCLUDE=-I$CLHEPPATH/include
fi
AC_MSG_RESULT([$CLHEPINCLUDE])
# Now lets see if the libraries work properly
oldLIBS="$LIBS"
oldLDFLAGS="$LDFLAGS"
oldCPPFLAGS="$CPPFLAGS"
LIBS="$LIBS $CLHEPLIB"
LDFLAGS="$LDFLAGS $CLHEPLDFLAGS"
CPPFLAGS="$CPPFLAGS $CLHEPINCLUDE"
# check CLHEP first
AC_MSG_CHECKING([that CLHEP works])
AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <CLHEP/Random/Random.h>]],[[using namespace CLHEP; HepRandom r; r.flat();]])],[AC_MSG_RESULT([yes])],[AC_MSG_RESULT([no])
AC_MSG_ERROR([CLHEP must be installed to continue.])
])
LIBS="$oldLIBS"
LDFLAGS="$oldLDFLAGS"
CPPFLAGS="$oldCPPFLAGS"
AC_SUBST(CLHEPLIB)
AC_SUBST(CLHEPLDFLAGS)
AC_SUBST(CLHEPINCLUDE)
])
AC_DEFUN([AC_CHECK_HEPMC],
[
AC_REQUIRE([AC_CHECK_CLHEP])
AC_MSG_CHECKING([for HepMC location])
HEPMCINCLUDE=""
HEPMCLIBS="-lHepMC"
AC_ARG_WITH(HepMC,
AC_HELP_STRING([--with-HepMC=path],[location of HepMC installation]),
[],
[with_HepMC="CLHEP"])
if test "x$with_HepMC" = "xno"; then
AC_MSG_RESULT([HepMC support disabled])
else
if test "$with_HepMC" = "CLHEP"; then
if test -f "${CLHEPINCLUDE#-I}/CLHEP/HepMC/GenEvent.h"; then
AC_MSG_RESULT([part of CLHEP])
HEPMCINCLUDE=$CLHEPINCLUDE/CLHEP
HEPMCLIBS=""
else
AC_MSG_RESULT([not found in CLHEP])
fi
else
AC_MSG_RESULT([$with_HepMC])
HEPMCINCLUDE=-I$with_HepMC/include
HEPMCLIBS="-L$with_HepMC/lib -R$with_HepMC/lib -lHepMC"
fi
# Now lets see if the libraries work properly
oldLIBS="$LIBS"
oldLDFLAGS="$LDFLAGS"
oldCPPFLAGS="$CPPFLAGS"
LIBS="$LIBS $CLHEPLIB $HEPMCLIBS"
LDFLAGS="$LDFLAGS $CLHEPLDFLAGS"
CPPFLAGS="$CPPFLAGS $CLHEPINCLUDE $HEPMCINCLUDE"
# check HepMC
AC_MSG_CHECKING([that HepMC works])
AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <HepMC/GenEvent.h>
]],[[HepMC::GenEvent();]])],[AC_MSG_RESULT([yes])],[AC_MSG_RESULT([no])
AC_MSG_ERROR([Use '--with-HepMC=' to set a path or use '--without-HepMC'.])
])
LIBS="$oldLIBS"
LDFLAGS="$oldLDFLAGS"
CPPFLAGS="$oldCPPFLAGS"
fi
AM_CONDITIONAL(HAVE_HEPMC,[test "x$with_HepMC" != "xno"])
AC_SUBST(HEPMCINCLUDE)
AC_SUBST(HEPMCLIBS)
])
AC_DEFUN([AC_CHECK_THEPEG],
[
AC_REQUIRE([AC_CHECK_CLHEP])
AC_MSG_CHECKING([for THEPEGPATH])
if test -z "$THEPEGPATH"; then
AC_MSG_RESULT([none])
AC_MSG_ERROR([THEPEGPATH not set])
fi
AC_MSG_RESULT([$THEPEGPATH])
THEPEGLIB="-lThePEG"
THEPEGLDFLAGS="-L$THEPEGPATH/lib/ThePEG"
AC_MSG_CHECKING([for THEPEGINCLUDE])
if test -z "$THEPEGINCLUDE"; then
THEPEGINCLUDE=-I$THEPEGPATH/include
fi
AC_MSG_RESULT([$THEPEGINCLUDE])
dnl ###############################
dnl ###############################
dnl Now lets see if the libraries work properly
oldLIBS="$LIBS"
oldLDFLAGS="$LDFLAGS"
oldCPPFLAGS="$CPPFLAGS"
LIBS="$oldLIBS $THEPEGLIB $CLHEPLIB -ldl"
LDFLAGS="$oldLDFLAGS $THEPEGLDFLAGS $CLHEPLDFLAGS"
CPPFLAGS="$oldCPPFLAGS $CLHEPINCLUDE $THEPEGINCLUDE"
AC_MSG_CHECKING([that ThePEG works])
AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ThePEG/Repository/Repository.h>
]], [[breakThePEG();
]])],[AC_MSG_RESULT([yes])
],[AC_MSG_RESULT([no])
AC_MSG_ERROR([ThePEG must be installed to continue.])])
LIBS="$oldLIBS"
LDFLAGS="$oldLDFLAGS"
CPPFLAGS="$oldCPPFLAGS"
AC_SUBST(THEPEGLIB)
AC_SUBST(THEPEGLDFLAGS)
AC_SUBST(THEPEGINCLUDE)
])
AC_DEFUN([AC_CHECK_KTJET],[
AC_REQUIRE([AC_CHECK_CLHEP])
AC_MSG_CHECKING([KTJETPATH is])
LOAD_KTJET=""
if test -z "$KTJETPATH"; then
AC_MSG_RESULT([*** No KtJet path set... won't build KtJet interface ***])
else
AC_MSG_RESULT("$KTJETPATH")
AC_MSG_CHECKING([KTJETLIBS is])
if test -z "$KTJETLIBS"; then
KTJETLIBS="-L$KTJETPATH/lib -R$KTJETPATH/lib -lKtEvent"
fi
KTJETLIBS="$KTJETLIBS $CLHEPLDFLAGS $CLHEPLIB"
AC_MSG_RESULT("$KTJETLIBS")
AC_MSG_CHECKING([KTJETINCLUDE is])
if test -z "$KTJETINCLUDE"; then
KTJETINCLUDE="-I$KTJETPATH/include"
fi
KTJETINCLUDE="$KTJETINCLUDE $CLHEPINCLUDE"
AC_MSG_RESULT("$KTJETINCLUDE")
LOAD_KTJET="read KtJetAnalysis.in"
fi
AC_SUBST(LOAD_KTJET)
AM_CONDITIONAL(WANT_LIBKTJET,[test ! -z "$KTJETPATH"])
AC_SUBST(KTJETPATH)
AC_SUBST(KTJETLIBS)
AC_SUBST(KTJETINCLUDE)
])
AC_DEFUN([AC_LOOPTOOLS],
[
AC_MSG_CHECKING([whether to build Looptools dependent parts])
AC_ARG_ENABLE(looptools,
AC_HELP_STRING([--disable-looptools],[turn off Looptools-dependent parts.]),
[],
[enable_looptools=yes]
)
AC_MSG_RESULT([$enable_looptools])
AM_CONDITIONAL(WANT_LOOPTOOLS,[test "x$enable_looptools" = "xyes"])
])
AC_DEFUN([AC_PDF_PATH],
[
AC_MSG_CHECKING([which Herwig++ PDF data to use])
AC_ARG_WITH(PDF,
AC_HELP_STRING([--with-PDF=path],[installation path of Herwig++PDF data tarball]),
[],
[with_PDF=${prefix}]
)
HERWIG_PDF_DEFAULT=${with_PDF}/share/Herwig++PDF/mrst/1998/lo05a.dat
if test -f "${HERWIG_PDF_DEFAULT}"; then
AC_MSG_RESULT([$with_PDF])
localPDFneeded=false
else
AC_MSG_RESULT([Using built-in PDF data set. For other data sets, set --with-PDF.])
HERWIG_PDF_DEFAULT=../PDF/mrst/1998/lo05a.dat
localPDFneeded=true
fi
AM_CONDITIONAL(WANT_LOCAL_PDF,[test "x$localPDFneeded" = "xtrue"])
AC_SUBST(HERWIG_PDF_DEFAULT)
])
AC_DEFUN([AC_CHECK_EVTGEN],
[
AC_MSG_CHECKING([for EVTGEN])
AC_ARG_WITH(evtgen,
AC_HELP_STRING([--with-evtgen=path],[installation path of EvtGen]),
[],
[
with_evtgen=no
])
EVTGENPATH=
if test "x$with_evtgen" = "xno"; then
AC_MSG_RESULT([not required])
else
AC_MSG_RESULT([$with_evtgen])
oldLIBS="$LIBS"
oldLDFLAGS="$LDFLAGS"
oldCPPFLAGS="$CPPFLAGS"
# Now lets see if the libraries work properly
LIBS="$LIBS $CLHEPLIB $HEPMCLIBS"
LDFLAGS="$LDFLAGS $CLHEPLDFLAGS"
CPPFLAGS="$CPPFLAGS $CLHEPINCLUDE $HEPMCINCLUDE"
tmpcxxflags=$CXXFLAGS
CXXFLAGS="$CXXFLAGS -L${with_evtgen}/lib"
AC_CHECK_LIB([evtgenlhc],[abort],
[],
[
AC_MSG_ERROR([libevtgenlhc could not be found at ${with_evtgen}/lib])
])
LIBS="$oldLIBS"
LDFLAGS="$oldLDFLAGS"
CPPFLAGS="$oldCPPFLAGS"
CXXFLAGS=$tmpcxxflags
EVTGENPATH=$with_evtgen
fi
AM_CONDITIONAL(WANT_EVTGEN,[test "x$with_evtgen" != "xno"])
AC_SUBST(EVTGENPATH)
])
File Metadata
Details
Attached
Mime Type
text/x-m4
Expires
Tue, Sep 30, 5:47 AM (1 d, 2 h)
Storage Engine
blob
Storage Format
Raw Data
Storage Handle
6553013
Default Alt Text
acinclude.m4 (6 KB)
Attached To
Mode
rHERWIGHG herwighg
Attached
Detach File
Event Timeline
Log In to Comment