Page MenuHomeHEPForge
Files F8308717

configure.ac
No OneTemporary
Actions

configure.ac
View Options

dnl configure.ac -- Main configuration script for WHIZARD
dnl
dnl Process this file with autoconf to produce a configure script.
dnl ************************************************************************
dnl configure -- Main configuration script for WHIZARD
dnl configure.ac -- WHIZARD configuration
dnl
dnl (C) 1999-2009 by
dnl Wolfgang Kilian <kilian@hep.physik.uni-siegen.de>
dnl Thorsten Ohl <ohl@physik.uni-wuerzburg.de>
dnl Juergen Reuter <juergen.reuter@physik.uni-freiburg.de>
dnl and others
dnl
dnl WHIZARD is free software; you can redistribute it and/or modify it
dnl under the terms of the GNU General Public License as published by
dnl the Free Software Foundation; either version 2, or (at your option)
dnl any later version.
dnl
dnl WHIZARD is distributed in the hope that it will be useful, but
dnl WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
dnl GNU General Public License for more details.
dnl
dnl You should have received a copy of the GNU General Public License
dnl along with this program; if not, write to the Free Software
dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
dnl
dnl ***********************************************************************
dnl Environment variables that can be set by the user:
dnl FC Fortran compiler
dnl FCFLAGS Fortran compiler flags
dnl
dnl ***********************************************************************
dnl Start configuration
AC_INIT([WHIZARD],[2.0.0])
AM_INIT_AUTOMAKE
AC_PREREQ([2.60])
########################################################################
### Package-specific initialization
WO_CONFIGURE_SECTION([Start of package configuration])
### Further version information
PACKAGE_DATE="Aug 24 2009"
PACKAGE_STATUS="alpha"
AC_SUBST(PACKAGE_DATE)
AC_SUBST(PACKAGE_STATUS)
AC_MSG_NOTICE([Package name: AC_PACKAGE_NAME()])
AC_MSG_NOTICE([Version: AC_PACKAGE_VERSION()])
AC_MSG_NOTICE([Date: $PACKAGE_DATE])
AC_MSG_NOTICE([Status: $PACKAGE_STATUS])
### Dump Package version and date to file 'VERSION'
echo "$PACKAGE_STRING ($PACKAGE_STATUS) $PACKAGE_DATE" \
> VERSION
### Read in user defaults (in addition to the ones in CONFIG_SITE, if set)
if test -r config.site; then
AC_MSG_NOTICE([loading site-specific configure script config.site])
. ./config.site
fi
### Source directory, for testing purposes
SRCDIR=`cd $srcdir && pwd`
AC_SUBST([SRCDIR])
### Build directory, for testing purposes
BUILDDIR=`pwd`
AC_SUBST([BUILDDIR])
### Location of installed libraries and such
eval PKGLIBDIR=$libdir/$PACKAGE
case $PKGLIBDIR in
NONE*) eval PKGLIBDIR=$prefix/lib/$PACKAGE ;;
esac
case $PKGLIBDIR in
NONE*) eval PKGLIBDIR=$ac_default_prefix/lib/$PACKAGE ;;
esac
AC_SUBST([PKGLIBDIR])
### Location of installed system-independent data
eval PKGDATADIR=$datarootdir/$PACKAGE
case $PKGDATADIR in
NONE*) eval PKGDATADIR=$prefix/share/$PACKAGE ;;
esac
case $PKGDATADIR in
NONE*) eval PKGDATADIR=$ac_default_prefix/share/$PACKAGE ;;
esac
AC_SUBST([PKGDATADIR])
### Location of installed TeX files and such
eval PKGTEXDIR=$datarootdir/tex/$PACKAGE
case $PKGTEXDIR in
NONE*) eval PKGTEXDIR=$prefix/tex/inputs/$PACKAGE ;;
esac
case $PKGTEXDIR in
NONE*) eval PKGTEXDIR=$ac_default_prefix/tex/inputs/$PACKAGE ;;
esac
AC_SUBST([PKGTEXDIR])
########################################################################
### Required programs and checks
###---------------------------------------------------------------------
### GNU Tools
WO_CONFIGURE_SECTION([Generic tools])
### Initialize LIBTOOL
LT_INIT()
LT_PREREQ([2.2])
### We include the m4 macro tool here
AC_PATH_PROG(M4,m4,false)
###---------------------------------------------------------------------
### Dynamic runtime linking
WO_CONFIGURE_SECTION([Dynamic runtime linking])
### Look for libdl (should provide 'dlopen' and friends)
WO_PROG_DL()
###---------------------------------------------------------------------
### Noweb
WO_CONFIGURE_SECTION([Checks for 'noweb' system])
### Enable/disable noweb and determine locations of notangle, cpif, noweave
WO_PROG_NOWEB()
###---------------------------------------------------------------------
### LaTeX
WO_CONFIGURE_SECTION([Checks for 'LaTeX' system])
### Determine whether LaTeX is present
AC_PROG_LATEX()
AC_PROG_DVIPS()
AC_PROG_PDFLATEX()
AC_PROG_PS2PDF()
AC_PROG_EPSTOPDF()
AC_PROG_GZIP()
AC_PATH_PROG(ACROREAD,acroread,false)
AC_PATH_PROG(GHOSTVIEW,gv ghostview,false)
AC_PATH_PROG(DOT,dot,false)
### Determine whether Metapost is present and whether event display is possible
AC_PROG_MPOST()
WO_CHECK_EVENT_ANALYSIS_METHODS()
### We put here the check for HEVEA components as well
WO_PROG_HEVEA()
###---------------------------------------------------------------------
### Fortran compiler
WO_CONFIGURE_SECTION([Fortran compiler checks])
### Determine default compiler to use
AC_PROG_FC()
### Determine compiler vendor and version
WO_FC_GET_VENDOR_AND_VERSION()
### Do we still need this? Check for .f95 acceptance
FC_FIND_EXTENSION([FC_EXT], [$FC], [f03 f95 f90])
### Require extension '.f90' for all compiler checks
AC_FC_SRCEXT([f90])
### Determine flags and extensions
WO_FC_PARAMETERS()
### Determine flags for linking the Fortran runtime library
WO_FC_LIBRARY_LDFLAGS()
### Check for Fortran 95 features
WO_FC_CHECK_F95()
### Check for allocatable subobjects (TR15581)
WO_FC_CHECK_TR15581()
### Check for allocatable scalars
WO_FC_CHECK_ALLOCATABLE_SCALARS()
### Check for ISO C binding support
WO_FC_CHECK_C_BINDING()
### Check for procedures pointers and abstract interfaces
WO_FC_CHECK_PROCEDURE_POINTERS()
### Check for type extension and further OO features
WO_FC_CHECK_OO_FEATURES()
### Check for F2003 command-line interface
WO_FC_CHECK_CMDLINE()
### Check for quadruple precision support
WO_FC_CHECK_QUADRUPLE()
### Check for quadruple precision support in the C interface
WO_FC_CHECK_QUADRUPLE_C()
### Quadruple precision enforced upon request
WO_FC_SET_PRECISION()
### Profiling compilation enforced upon request
WO_FC_SET_PROFILING()
### Profiling compilation enforced upon request
WO_FC_SET_OMEGA_IMPURE()
###
FC_MODULE_FILE([FC_MODULE_NAME], [FC_MODULE_EXT], [$FC], [$FC_EXT])
WO_FC_FILENAME_CASE_CONVERSION
AC_SUBST([FC_MAKE_MODULE_NAME])
case "$FC_MODULE_NAME" in
module_NAME)
FC_MAKE_MODULE_NAME='$*.$(FC_MODULE_EXT)'
;;
module_name)
FC_MAKE_MODULE_NAME='"`echo $* | $(LOWERCASE)`".$(FC_MODULE_EXT)'
;;
MODULE_NAME)
FC_MAKE_MODULE_NAME='"`echo $* | $(UPPERCASE)`".$(FC_MODULE_EXT)'
;;
conftest)
FC_MAKE_MODULE_NAME='$*.$(FC_MODULE_EXT)'
;;
*)
;;
esac
###---------------------------------------------------------------------
### O'Caml
WO_CONFIGURE_SECTION([Objective Caml checks])
### Check for ocamlc and its relatives
AC_PROG_OCAML()
if test "$enable_ocaml" != "no"; then
AC_OCAML_VERSION_CHECK(304000)
AC_PROG_OCAMLLEX()
AC_PROG_OCAMLYACC()
AC_PROG_OCAMLCP()
### Ocamlweb is required to be newer than v0.9
AC_PROG_OCAMLWEB(009000)
AC_PROG_OCAML_LABLGTK()
AC_PATH_PROGS(OCAMLDOT,ocamldot)
AC_PATH_PROGS(OCAMLDEFUN,ocamldefun)
else
AC_MSG_NOTICE([WARNING: O'Caml and O'Mega matrix elements disabled by request!])
fi
########################################################################
### Libraries
###---------------------------------------------------------------------
### LHAPDF
WO_CONFIGURE_SECTION([LHAPDF])
WO_PROG_LHAPDF()
###---------------------------------------------------------------------
### HepMC
WO_CONFIGURE_SECTION([HepMC])
WO_PROG_HEPMC()
########################################################################
### Miscellaneous
WO_CONFIGURE_SECTION([Numerical checks])
###---------------------------------------------------------------------
### Disable default checks upon request
AC_ARG_ENABLE([default_checks],
[AS_HELP_STRING([--disable-default-checks],
[disable the default self-checks [[no]]])])
AC_CACHE_CHECK([whether we want the default self-checks],
[wo_cv_default_checks],
[dnl
if test "$enable_default_checks" != "no"; then
wo_cv_default_checks=yes
else
wo_cv_default_checks=no
fi])
AM_CONDITIONAL([DEFAULT_CHECKS],
[test "$enable_default_checks" != "no"])
###---------------------------------------------------------------------
### Enable numerical checks upon request
AC_ARG_ENABLE([susy_checks],
[AS_HELP_STRING([--enable-susy-checks],
[enable time-consuming SUSY checks [[no]]])])
AC_CACHE_CHECK([whether we want extra SUSY checks],
[wo_cv_susy_checks],
[dnl
if test "$enable_susy_checks" = "yes"; then
wo_cv_susy_checks=yes
else
wo_cv_susy_checks=no
fi])
AM_CONDITIONAL([SUSY_CHECKS],
[test "$enable_susy_checks" = "yes"])
########################################################################
### Wrapup
WO_CONFIGURE_SECTION([Finalize configuration])
###---------------------------------------------------------------------
### Main directory
AC_CONFIG_FILES([Makefile whizard-setup.sh] [whizard-setup.csh])
###---------------------------------------------------------------------
### Subdirectory src
AC_CONFIG_FILES([src/Makefile])
###---------------------------------------------------------------------
### Subdirectory src/hepmc
AC_CONFIG_FILES([src/hepmc/Makefile])
###---------------------------------------------------------------------
### Subdirectory src/lhapdf: dummy library as LHAPDF replacement
AC_CONFIG_FILES([src/lhapdf/Makefile])
###---------------------------------------------------------------------
### Subdirectory src/misc: numeric kinds, strings
AC_CONFIG_FILES([src/misc/Makefile] [src/misc/kinds.f90] [src/misc/system_dependencies.f90])
###---------------------------------------------------------------------
### Subdirectory src/models
AC_CONFIG_FILES([src/models/Makefile])
dnl ########################################################################
dnl ### The following will eventually be replaced by
dnl AC_CONFIG_SUBDIRS([src/vamp])
dnl ########################################################################
###---------------------------------------------------------------------
### Subdirectory src/vamp
AC_CONFIG_FILES([src/vamp/Makefile])
###---------------------------------------------------------------------
### Subdirectory src/whizard-core
AC_CONFIG_FILES([src/whizard-core/Makefile])
### AC_CONFIG_FILES([src/whizard-core/Makefile] [src/whizard-core/lhapdf.inc])
###---------------------------------------------------------------------
### Subdirectory src/prebuilt
AC_CONFIG_FILES([src/prebuilt/Makefile])
dnl ########################################################################
dnl ### The following will eventually be replaced by
dnl AC_CONFIG_SUBDIRS([src/omega])
dnl ########################################################################
# comment_model_file=""
comment_model_file="#"
AC_SUBST([comment_model_file])
###---------------------------------------------------------------------
### Subdirectory src/omega
AC_CONFIG_FILES([src/omega/Makefile:src/omega/src/Makefile.include:src/omega/Makefile.in])
###---------------------------------------------------------------------
### Subdirectory src/omega/bin
AC_CONFIG_FILES([src/omega/bin/Makefile:src/omega/src/Makefile.include:src/omega/bin/Makefile.in])
###---------------------------------------------------------------------
### Subdirectory src/omega/doc
AC_CONFIG_FILES([src/omega/doc/Makefile:src/omega/src/Makefile.include:src/omega/doc/Makefile.in])
### We do not make the extensions and tests Makefiles by default
###---------------------------------------------------------------------
### Subdirectory src/omega/lib
AC_CONFIG_FILES([src/omega/lib/Makefile:src/omega/src/Makefile.include:src/omega/lib/Makefile.in])
###---------------------------------------------------------------------
### Subdirectory src/omega/models
AC_CONFIG_FILES([src/omega/models/Makefile:src/omega/src/Makefile.include:src/omega/models/Makefile.in])
###---------------------------------------------------------------------
### Subdirectory src/omega/src
AC_CONFIG_FILES([src/omega/src/Makefile:src/omega/src/Makefile.include:src/omega/src/Makefile.in])
###---------------------------------------------------------------------
### Subdirectory src/omega/web
AC_CONFIG_FILES([src/omega/web/Makefile:src/omega/src/Makefile.include:src/omega/web/Makefile.in])
###---------------------------------------------------------------------
### Subdirectory src/omega/tools
AC_CONFIG_FILES([src/omega/tools/Makefile:src/omega/src/Makefile.include:src/omega/tools/Makefile.in])
###---------------------------------------------------------------------
### Subdirectory src/circe
AC_CONFIG_FILES([src/circe/Makefile])
###---------------------------------------------------------------------
### Subdirectory src/gamelan: WHIZARD graphics package
AC_CONFIG_FILES([src/gamelan/Makefile] [src/gamelan/gml])
###---------------------------------------------------------------------
### Subdirectory share
AC_CONFIG_FILES([share/Makefile])
###---------------------------------------------------------------------
### Subdirectory share/doc
AC_CONFIG_FILES([share/doc/Makefile])
###---------------------------------------------------------------------
### Subdirectory share/models
AC_CONFIG_FILES([share/models/Makefile])
###---------------------------------------------------------------------
### Subdirectory share/susy
AC_CONFIG_FILES([share/susy/Makefile])
###---------------------------------------------------------------------
### Subdirectory share/susy
AC_CONFIG_FILES([share/test/Makefile])
###---------------------------------------------------------------------
### Subdirectory test
AC_CONFIG_FILES([test/Makefile])
AC_CONFIG_FILES([test/run_whizard.sh], [chmod u+x test/run_whizard.sh])
########################################################################
# FORTRAN options for the configure script
########################################################################
########################################################################
# O'Mega options for the configure script
########################################################################
###---------------------------------------------------------------------
### Switches for O'Mega models
WO_SET_OMEGA_UNRELEASED()
WO_SET_OMEGA_UNSUPPORTED()
WO_SET_OMEGA_THEORETICAL()
WO_SET_OMEGA_REDUNDANT()
WO_SET_OMEGA_DEVELOPERS()
WO_SET_OMEGA_OBSOLETE()
WO_SET_OMEGA_GUI()
###---------------------------------------------------------------------
### Select specific O'Mega programs
AC_ARG_ENABLE([OMEGA_PROGRAM],
[ --enable-omega-program=name Build only one or more selected applications.],
[case "$enableval" in
no) SELECT_OMEGA_CUSTOM=""
;;
*) SELECT_OMEGA_CUSTOM="$SELECT_OMEGA_CUSTOM $enableval"
;;
esac])
###---------------------------------------------------------------------
AC_OUTPUT()
########################################################################

File Metadata

Mime Type
text/x-m4
Expires
Sat, Dec 21, 12:57 PM (1 d, 7 h)
Storage Engine
blob
Storage Format
Raw Data
Storage Handle
4022856
Default Alt Text
configure.ac (14 KB)

Event Timeline